$!	This is the default LOGIN procedure file.
$!
$! Define symbols for later use
$ SCSNODE = f$edit(f$getsyi("SCSNODE"), "TRIM, UPCASE")
$ DFLTDIR = f$edit(f$environment("DEFAULT"), "TRIM, UPCASE")
$!
$! Foreign command to run DNS utility.
$ DNSCP :== $DNS$CONTROL
$! Foreign command to run JNET Monitor (JMONITOR) utility.
$ JM*ONITOR :== $JAN_SYS:JCP MONITOR
$!
$ goto 'f$mode()'
$INTERACTIVE:
$!	This is an interactive/terminal session.
$!
$! Check if the terminal line we're on is the system console
$ if f$getjpi("","TERMINAL") .eqs. "OPA0:" then goto _CONSOLE
$!
$! Not on the console; thus initiate the ALL-IN-1/WPS-PLUS environment setup.
$ @sys$manager:a1wpsplus_login
$!
$! Still not on the console; initialize the TEAMDATA logical.
$ 
$ TDB = f$edit(DFLTDIR + "TEAMDB.RDB", "TRIM, UPCASE")
$ if f$search(TDB) .nes. "" then -
      define/job teamdb 'TDB'
$!
$ goto _CONT
$!
$_CONSOLE:
$! On the system console terminal, do not do the ALL-IN-1/WPS-PLUS setup, and do
$! not query the terminal type (assume LA36 DECwriter, 80 column width).
$ set terminal/device_type=LA36/width=80
$!
$_CONT:
$! Setup MicroPower/Pascal-VMS for users on login.
$ @micropower$lib:mpsetup
$!
$ EXIT
$!
$!
$BATCH:
$!	This is a batch session.
$NETWORK:
$!	This is a network session.
$OTHER:
$!	This is an unknown session.
$!
$ EXIT
