$ ! ********************************************************************
$ ! *          Turnkey VAX/VMS System-Wide Login Command File          *
$ ! *                                                                  *
$ ! * Based  on the  example SYLOGIN.COM  file found  in the  "VAX/VMS *
$ ! * System Management and Operations Guide" (AA-M547A-TE).           *
$ ! ********************************************************************
$ V = F$VERIFY(0)
$START:
$ !
$ ON CONTROL_Y THEN GOTO START	! Don't allow Ctrl/Y out
$ SET NOON
$ !
$ !	Set default file protection back to the old default
$ !
$ SET PROTECTION=(SY:RWED,OW:RWED,GR:RWED,WO:RE)/DEFAULT
$ !
$ !	Make network jobs start faster
$ !
$ IF F$MODE() .EQS. "NETWORK" THEN GOTO EXIT
$ !
$ !	Enable Ctrl/T handling by DCL
$ SET CONTROL=T
$ !
$ !	Define foreign commands for installed utilities
$ !
$ CD		:== $SYS$SYSTEM:CD/INHIB
$ DNSCP		:== $DNS$CONTROL
$ INFO		:== SHOW PROCESS/CONTINUOUS
$ JM*ONITOR	:== $JAN_SYS:JCP MONITOR
$ MICRO2	:== $SYS$SYSTEM:MICRO2
$ RESUME	:== SET PROCESS/RESUME
$ RETOS		:== $RETOS
$ SD		:== $SYS$SYSTEM:CD/INHIB/AA/PARTIAL
$ SDA		:== ANALYZE/CRASH_DUMP
$ SETNAME	:== SET PROCESS/NAME
$ SUSPEND	:== SET PROCESS/SUSPEND
$ !
$ !	Define a symbol indicating whether
$ !	the terminal is on a dialup port.
$ !
$ TT == F$GETJPI("","TERMINAL")
$ DIALUP == ((TT .GES. "TXA0:" .AND. TT .LES. "TXA15:") -
	.OR. (TT .GES. "TXB0:" .AND. TT .LES. "TXB15:") -
	.OR. (TT .GES. "TXC0:" .AND. TT .LES. "TXC15:") -
	.OR. (TT .GES. "TXD0:" .AND. TT .LES. "TXD15:"))
$ IF DIALUP THEN SET TERMINAL/INQUIRE
$ !
$EXIT:
$ IF V THEN SET VERIFY
$ EXIT
