$ ! ********************************************************************
$ ! *       Turnkey VAX/VMS Individual User's Login Command File       *
$ ! *                                                                  *
$ ! * Based on the example LOGIN.COM file found in the "VAX/VMS System *
$ ! * Management and Operations Guide" (AA-M547A-TE).                  *
$ ! ********************************************************************
$ SET NOON
$ SET PROTECTION=(S=RD,O=RWED,G=R,W=R)/DEFAULT
$ !
$ !	Define abbreviations for often-used commands
$ !
$ DIR*ECTORY	:== DIRECTORY/DATE/SIZE
$ PH*ONE	:== PHONE/SCROLL
$ !
$ !	Other useful command abbreviations
$ !
$ DAY		:== SHOW TIME
$ H*OME		:== SET DEFAULT SYS$LOGIN
$ PRI*NT	:== PRINT/NOTIFY	
$ PWD		:== SHOW DEFAULT
$ SHP		:== SHOW PROCESSES/PRIVILEGES
$ SP		:== SET PROCESS/PRIVILEGES='P1
$ SQ		:== SHOW QUEUE/BATCH/ALL/DEVICE
$ SUB*MIT	:== SUBMIT/NOTIFY	
$ SYS*TAT	:== SHOW SYSTEM	
$ UP		:== SET DEFAULT [-]
$ !
$ !	Set /LOG for all commands
$ !
$ BACK*UP	:== BACKUP/LOG
$ DEL*ETE	:== DELETE/LOG
$ LIB*RARY	:== LIBRARY/LOG
$ PUR*GE	:== PURGE/LOG
$ REN*AME	:== RENAME/LOG
$ !
$ !	End of LOGIN.COM processing
$ !
$ GOTO 'F$MODE()'
$INTERACTIVE:
$ ! Setup the TEAMDATA logical, if the database exists
$ IF F$SEARCH("SYS$LOGIN:TEAMDB.RDB") .NES. "" THEN -
$	DEFINE/JOB TEAMDB SYS$LOGIN:TEAMDB.RDB
$ !
$ ! Setup ALL-IN-1/WPS-PLUS; if not on console
$ IF F$GETJPI("","TERMINAL") .NES. "OPA0:" THEN -
$	@SYS$MANAGER:A1WPSPLUS_LOGIN
$ !
$ ! Setup MicroPower/Pascal-VMS for users on login
$ @MICROPOWER$LIB:MPSETUP
$ !
$ ! Setup Storage Library System
$ @SYS$MANAGER:SLS$TAPSYMBOL
$ !
$ EXIT		! End of interactive login
$BATCH:
$ SET VERIFY
$NETWORK:
$OTHER:
$ EXIT		! End of non-interactive logins
